Voorbeeld 4 Aantal cliënten met een Wlz-indicatie per sector

Concepten

• Bedrijf
• Langdurige zorg sector
• Mens
• Verpleegproces
• Wlz-indicatie

Relaties

• deel van
• gaat over
• gedefinieerd door
• heeft deel
• heeft perdurantlocatie
• vestiging van

Eigenschappen

• einddatum
• startdatum

Instanties

• Sector GGZ, B-groep
• Sector GGZ, Wonen
• Sector Lichamelijk gehandicapt
• Sector Licht verstandelijk gehandicapt
• Sector Verpleging en verzorging
• Sector Verstandelijk gehandicapt
• Sector Zintuiglijk gehandicapt, auditief en communicatief
• Sector Zintuiglijk gehandicapt, visueel

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Kwaliteitsbeeld Voorbeeld 4 Aantal cliënten met een Wlz-indicatie per sector
2# Parameters:
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
6PREFIX onz-zorg: <http://purl.org/ozo/onz-zorg#>
7PREFIX onz-g: <http://purl.org/ozo/onz-g#>
8PREFIX onz-org: <http://purl.org/ozo/onz-org#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10
11SELECT 
12    ?Organisatie
13    (SUM(?vv) as ?aantal_vv)
14    (SUM(?lg) as ?aantal_lg)
15    (SUM(?lvg) as ?aantal_lvg)
16    (SUM(?vg) as ?aantal_vg)
17    (SUM(?zgaud) as ?aantal_zgaud)
18    (SUM(?zgvis) as ?aantal_zgvis)
19    (SUM(?ggzb) as ?aantal_ggzb)
20    (SUM(?ggzw) as ?aantal_ggzw)
21WHERE
22{
23    BIND ("2024-12-31"^^xsd:date AS ?peildatum)
24
25    #selecteer de zorgprocessen die voldoen aan de inclusiecriteria
26    ?zorgproces
27        a onz-zorg:NursingProcess ;
28        onz-g:definedBy ?indicatie ;
29        onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie ; # locatie bevat niet alleen vestigingen
30        onz-g:startDatum ?start_zorgproces .
31        OPTIONAL {?zorgproces onz-g:eindDatum ?eind_zorgproces}
32        FILTER (?start_zorgproces <= ?peildatum && ((?eind_zorgproces >= ?peildatum)||(!BOUND(?eind_zorgproces))))
33
34        ?locatie onz-org:vestigingVan ?organisatie_uri .
35        ?organisatie_uri
36            a onz-g:Business ;
37            rdfs:label ?Organisatie .
38
39    #selecteer de bijbehorende indicatie, om unieke clienten te kunnen bepalen
40    ?indicatie
41        a onz-zorg:WlzIndicatie ;
42        onz-g:hasPart/onz-g:isAbout ?sector ;
43        onz-g:isAbout ?client .
44
45    ?sector
46        a onz-zorg:LangdurigeZorgSector .
47    ?client a onz-g:Human .
48
49    #Per financieringsstroom
50    BIND(IF(?sector = onz-zorg:VV, 1, 0) AS ?vv)
51    BIND(IF(?sector = onz-zorg:LG, 1, 0) AS ?lg)
52    BIND(IF(?sector = onz-zorg:LVG, 1, 0) AS ?lvg)
53    BIND(IF(?sector = onz-zorg:VG, 1, 0) AS ?vg)
54    BIND(IF(?sector = onz-zorg:ZGAUD, 1, 0) AS ?zgaud)
55    BIND(IF(?sector = onz-zorg:ZGVIS, 1, 0) AS ?zgvis)
56    BIND(IF(?sector = onz-zorg:GGZ-B, 1, 0) AS ?ggzb)
57    BIND(IF(?sector = onz-zorg:GGZ-W, 1, 0) AS ?ggzw)
58}
59GROUP BY ?Organisatie
60ORDER BY ?Organisatie
61
62